Arduino DHT11の使い方｜ライブラリなしで温湿度を読む 練習問題7問

この記事では、温湿度センサDHT11の値を、専用ライブラリを使わずに読み取ります。データシートのタイミング仕様を自分で読み解いてセンサ入力値を取得できるようになりましょう。

DHT11はDHT.hのようなライブラリを使えば数行で読めます。ただ、それでは「なぜセンサ値を取得できるか」が分かりません。実務でセンサやICをつなぐと、ライブラリが用意されていないことは珍しくなく、そのときはデータシートを見て通信を自分で組みます。DHT11は、その練習にちょうどよい題材だと思います。

まずライブラリで動かす形を示し、次にスタート信号・応答・40ビットのデータを、パルスの長さを測って自力で読み取ります。パルスの長さを測るには、前の記事で扱った時間の考え方を使います。

＜自己紹介＞
筆者は現役の車載組込みソフトエンジニアです。センサのデータシートを読み、タイミングや特性を解析する作業は、未経験のころ一番苦戦したところでもあります。だからこそ、データシートのどこをどう読むかを具体的に示しながら進めます。

DHT11で学ぶこと

DHT11は、1本の信号線で温度と湿度を送ってくる安価なセンサです。データは決まった時間の並び（タイミング）で送られるので、その仕様どおりに読み取ります。

本記事のライブラリなし版は、Arduino Uno（ATmega328P）向けにPlatformIOでコンパイル確認しました。実際の温湿度が正しく読めるかは、手元のDHT11とUno R3で確認しながら進めてください。

準備するもの

信号線はD2につなぐ前提で説明します。値を画面で確認するので、先にシリアルのドリルを、時間の測り方はタイマのドリルを済ませておくと理解しやすくなります。

DHT11を配線する

DHT11モジュールは、Arduinoの5VをVCC、D2をDATA、GNDをGNDへつなぎます。モジュールによって端子の並びが異なるため、位置ではなく基板上の印字を確認してください。

基板の付いていない単体4ピンのDHT11では、正面から見て左からVCC、DATA、未接続、GNDです。DATAと5Vの間には約5kΩのプルアップ抵抗を入れます。

まずライブラリでDHT11を読む

最初に、専用ライブラリを使った読み方を見ておきます。マイコン下回りの処理が作成済みの関数なので、数行で温度と湿度が取れます。

#include <DHT.h>

DHT dht(2, DHT11);   // D2に接続、DHT11を指定

void setup() {
    Serial.begin(9600);
    dht.begin();
}

void loop() {
    float h = dht.readHumidity();
    float t = dht.readTemperature();

    Serial.print("humidity=");
    Serial.print(h);
    Serial.print("% temp=");
    Serial.print(t);
    Serial.println("C");

    delay(2000);     // 連続読み取りは1秒以上あける
}

これで動きますが、readHumidity()の中で何が起きているかは見えません。ここからは、この関数がやっていることを自分で書いてみます。

次にライブラリなしで読む

ライブラリなしで読むには、DHT11がどんな順番・どんな長さで信号を送るかを知る必要があります。これはレジスタのビットではなく、時間の並び（タイミング）としてデータシートに書かれています。まずそこを読み解きます。

データシートからタイミングを読み解く

DHT11のデータシートには、通信の手順が時間つきで載っています。順番に整理すると次のようになります。

① マイコンからスタート信号を送る

まずマイコンが「データをください」と合図します。信号線を一定時間Lowにしてから、Highに戻します。

② DHT11の応答を確認する

スタート信号を受けると、DHT11が応答を返します。この並びを確認できたら、データが続く合図です。

③ 40ビットのデータを、Highの長さで読む

続いて40ビットが送られます。各ビットは、まず約50µsのLowがあり、そのあとのHighの長さで0か1が決まります。短ければ0、長ければ1です。

0と1でHighの長さがはっきり違うので、間をとって約40µsより長ければ1、短ければ0と判定できます。40ビットは、次の5バイトの意味を持ちます。

チェックサムは、読み取りが正しかったかの確認用です。1〜4バイト目を足し合わせ、その下位8ビットが5バイト目と一致すれば、データは信用できます。

#define DHT_PIN 2
uint8_t dht_data[5];

// 指定レベルが続く間のマイクロ秒を、タイムアウト付きで測る
long wait_level(uint8_t level, unsigned long timeout_us) {
    unsigned long start = micros();
    while (digitalRead(DHT_PIN) == level) {
        if (micros() - start > timeout_us) {
            return -1;
        }
    }
    return (long)(micros() - start);
}

bool dht11_read(void) {
    uint8_t bits[5] = {0, 0, 0, 0, 0};

    // (1) スタート信号：Lowを18ms以上→High
    pinMode(DHT_PIN, OUTPUT);
    digitalWrite(DHT_PIN, LOW);
    delay(20);
    digitalWrite(DHT_PIN, HIGH);
    delayMicroseconds(30);
    pinMode(DHT_PIN, INPUT_PULLUP);

    // (2) 応答：Low約80us→High約80us
    if (wait_level(HIGH, 100) < 0) return false;
    if (wait_level(LOW, 100) < 0) return false;
    if (wait_level(HIGH, 100) < 0) return false;

    // (3) 40bitを読む：Highの長さで0/1を判定
    for (uint8_t i = 0; i < 40; i++) {
        if (wait_level(LOW, 100) < 0) return false;
        long high_len = wait_level(HIGH, 200);
        if (high_len < 0) return false;

        bits[i / 8] <<= 1;
        if (high_len > 40) {          // 約40usより長ければ1
            bits[i / 8] |= 1;
        }
    }

    // (4) チェックサム
    uint8_t sum = bits[0] + bits + bits + bits;
    if (sum != bits) return false;

    for (uint8_t i = 0; i < 5; i++) dht_data[i] = bits[i];
    return true;
}

練習問題（基礎5＋発展2）

基礎5問は、プロトコルの読み取りとデータの意味を確認します。発展2問は、パルス幅の判定とチェックサムを扱います。まず自分で考えてから回答を開いてください。

uint8_t sum = bits[0] + bits + bits + bits;
// sum の下位8ビットが bits と一致すればOK

bits[i / 8] <<= 1;          // 1つ左へずらして場所を空ける
if (high_len > 40) {
    bits[i / 8] |= 1;      // 長ければ最下位ビットを1に
}

例：実務で実際に書くコード

実務でも、ライブラリのないセンサやICは、データシートのタイミング図を見て通信を組みます。DHT11で身につけた「スタート信号を送る→応答を待つ→決められた並びで読む→チェックサムで確かめる」という流れは、多くのセンサに共通します。

/* 応答待ちには必ずタイムアウトを付ける */
if (wait_response(TIMEOUT) < 0) {
    return ERR_TIMEOUT;
}

/* 受信データは、チェックサムやCRCで必ず検証する */
if (calc_checksum(buf) != buf[LAST]) {
    return ERR_CHECKSUM;
}

車載の通信でも、受け取ったデータをそのまま信じず、チェックサムやCRCで壊れていないかを確かめます。「応答にはタイムアウト、受信データには検証」は、外部と通信するときの基本の作法です。総合課題でも、DHT11の値をこの形で読み、異常なら使わないようにします。

最後につまずきポイントをおさらい

もう一つは、タイミングがずれると0と1を読み違える点です。delayMicroseconds()やmicros()の精度、割り込みによる遅れが影響することもあります。読み取り中は割り込みを一時的に止める方法もありますが、まずは間隔をあけて何度か読み、チェックサムが合う値だけを使うのが確実。DHT11は湿度の小数部が0のことが多く、より細かく測りたいときはDHT22などの上位のセンサを使います。

よくある質問（FAQ）

ライブラリを使ってはいけないのですか？

実際の開発ではライブラリを使ってかまいません。このドリルの目的は、ライブラリの中で何が起きているかを理解することです。中身が分かっていれば、ライブラリがないセンサや、うまく動かないときにも対応できます。

読み取りに失敗します

配線（信号線がD2か、電源とGNDが合っているか）、読み取り間隔（2秒ほどあけているか）をまず確認します。モジュール版でない素のDHT11では、信号線と電源の間にプルアップ抵抗が必要です。チェックサムが合わない値は使わず、次の読み取りを待つのが安全です。

DHT11とDHT22の違いは何ですか？

通信の考え方はほぼ同じですが、DHT22のほうが測定範囲が広く、小数部まで細かく測れます。まずDHT11で読み方を身につければ、DHT22へも同じ手順で応用できます。

次に読む

センサの値を読めるようになったら、次は出力側です。赤外線リモコンの信号を解析して、エアコンなどの家電を操作する練習へ進みます。DHT11で身につけた「タイミングを読む」考え方が、今度は信号を送る側で生きてきます。

• Arduino タイマのドリル（#3）：時間の測り方と周期処理を復習する
• C言語 ビット演算の練習問題：ビットを積む・取り出す操作を確認する
• Arduino 赤外線リモコンのドリル（#5・作成中）：信号を解析してエアコンを操作する