Arduino日本語リファレンス｜UNO R3/R4で使用する関数の解説

Arduinoの関数を日本語で調べようとすると、たどり着くのは2010年前後で更新が止まったページか、英語の公式ドキュメントです。関数名と意味は分かっても、実際どれくらい時間がかかるのか、どちらを使えばいいのかまでは書かれていません。

この記事は、Arduinoの関数を分類から引ける一覧にしたうえで、UNO R3とUNO R4の実機で測った値を並べたものです。載せているのは、数字で確かめたものだけです。digitalWrite()は1回4.980マイクロ秒。millis()が1回で進むのは1.024ms。tone()を鳴らすと特定のピンのPWMが止まります。

この記事の使い方

関数はArduino公式のLanguage Referenceと同じ分類で並べています。公式ドキュメントと行き来しても迷わないようにするためです（公式は英語です）。

そのうえで、他のリファレンスに無い情報を2つ足しました。

Arduinoで書いているコードがそもそも何の言語なのかは、Arduinoの言語は何？C言語・C++との違いを現役組み込みエンジニアが解説で説明しています。

デジタルI/O｜ピンをHIGH/LOWで扱う

pinMode(8, OUTPUT);

unsigned long start = micros();
for (uint16_t i = 0; i < 1000; i++) {
    digitalWrite(8, HIGH);
}
Serial.println((micros() - start) / 1000.0, 3);

/* 同じ動作をレジスタ直接で。D8＝PORTBの0ビット目 */
/* AVR（UNO R3）だけ。R4では動かない */
start = micros();
for (uint16_t i = 0; i < 1000; i++) {
    PORTB |= _BV(PB0);
}
Serial.println((micros() - start) / 1000.0, 3);

digitalWrite が「遅い」と言われる理由｜実測で89倍

digitalWrite()は、渡されたピン番号から毎回テーブルを引いて、どのレジスタのどのビットかを調べ、割り込みを止めてから書き込みます。安全な代わりに手間がかかります。

レジスタを直接書けば同じ動作が終わります。UNO R3で両方を1,000回ずつ呼んで測りました。

レジスタを直接触る書き方はArduino Lチカのやり方｜digitalWriteからレジスタ操作まで練習問題9問で、同じLチカを両方の書き方で試せます。

INPUT_PULLUP は内蔵の抵抗を使う設定

スイッチを読むときINPUTのままだと、スイッチが開いている間のピンの電圧が定まらず、読むたびに値が変わります。INPUT_PULLUPにすると内部の抵抗でピンが5V側へ引き上げられ、スイッチを押したときだけLOWになります。外付けの抵抗が要りません。

この内蔵抵抗の値を、外付けの10kΩとの分圧から逆算して測りました。UNO R3で約37〜44kΩ（5回の測定）。ATmega328Pのデータシートは20〜50kΩと幅のある書き方をしていますが、その範囲に収まっています。同じ個体でも測るたびに数kΩ動くので、設計で当てにする値ではありません。

アナログI/O｜電圧を読む・PWMを出す

long sum = 0;
int lo = 1023;
int hi = 0;

for (uint16_t i = 0; i < 200; i++) {
    int v = analogRead(A0);
    sum += v;
    if (v < lo) {
        lo = v;
    }
    if (v > hi) {
        hi = v;
    }
}

/* 平均電圧 */
double volt = (sum / 200.0) * 5.0 / 1023.0;

/* 振れ幅（LSB）。大きいならノイズを疑う */
Serial.println(hi - lo);

/* PWMを出す。128 でデューティ約50% */
analogWrite(3, 128);

analogWrite は電圧を出す関数ではない

出ているのはHIGHとLOWの繰り返しです。名前がanalogWriteなので「指定した電圧が出る」と読めますが、そうではありません。analogWrite(pin, 128)なら、およそ半分の時間だけ5Vになる波形が出続けます。

テスタで測ると中間の電圧に見えるのは、テスタが平均を表示しているからです。確かめるために、PWMの出力を抵抗とコンデンサで平滑して、平均電圧を実際に測りました。

理論値との差は最大0.9%でした。値と平均電圧はきれいに比例します。ただし出ているのはあくまで5Vと0Vの繰り返しで、LEDが暗く見えるのも、モータがゆっくり回るのも、平均の電力が下がるからです。

PWMの周波数はピンによって違う（R3）

UNO R3でPWMを出せるのは3・5・6・9・10・11番ピン（基板に「〜」が付いています）。このピンは内部で複数のタイマに割り当てられていて、担当するタイマが違うと周波数も違います。同じanalogWrite(128)を出して測りました。

R3ではピンによって周波数が倍違います。モータが可聴域で唸る、LEDがちらついて見えるといった症状は、この違いで説明が付くことがあります。R4ではどちらも同じ491Hzで、この差はありません。

時間｜待つ・測る

delay と millis の使い分け

millis()で周期処理を書くときは、前回の時刻を覚えておいて引き算で判定します。

unsigned long last = 0;

void loop(void)
{
    unsigned long now = millis();

    if ((now - last) >= 1000) {
        last = now;
        /* ここに1秒ごとの処理 */
    }

    /* ここは止まらずに毎回まわる */
}

now >= last + 1000 ではなく (now - last) >= 1000 と書くのは、49.7日で0に戻ったときにも正しく動かすためです。引き算なら桁が一周しても差は正しく求まります。

周期処理そのものの練習はArduinoで一定周期の処理を作る｜millisとタイマ割り込みの練習問題にまとめています。

millis() は1.000msずつ進まない（R3）

millis()の値が1つ進む実際の時間を測ったところ、UNO R3で1024.0マイクロ秒でした。1.000msではありません。

理由はArduinoのソースに書いてあります。AVR版のコア（wiring.c）では、時間を数えているタイマが一周するのが1024µsで、そのたびにmillis()を1進めています。

つまり1歩は1.024msですが、42回に1回2進む補正が入るので、長い目で見た平均は1.000msになります。数秒の周期処理で困ることはありませんが、1歩を1msとして積算すると少しずつずれることは知っておいてください。UNO R4では999.7〜1000.0µsで、この補正は要りません。

delayMicroseconds(1) は何もしない

指定値と実際の待ち時間を、50回ずつ呼んで測りました。

R3で1µsの指定が待ち時間にならないのは仕様です。コアのソースにif (us <= 1) return;と書かれていて、1以下なら何もせずに返ります。コメントには「関数を呼ぶ手間だけで約1µs使うから」と理由も書かれています。

1µs前後の待ちが要る場面では、この関数を当てにしないのが正解です。なお100µsの指定だけ約1割長くなりましたが、原因は特定できていないため、実測値だけを載せます。

外部割り込み｜待たずに拾う

volatile unsigned long isr_time_us = 0;
volatile bool isr_fired = false;

void on_rise(void)
{
    /* 記録だけ。Serial.print は呼ばない */
    isr_time_us = micros();
    isr_fired = true;
}

void setup(void)
{
    pinMode(2, INPUT);
    attachInterrupt(digitalPinToInterrupt(2), on_rise, RISING);
}

割り込みは「すぐ」ではない

ピンが変化してから割り込み関数の中に入るまでの時間を測りました。UNO R3で11.20マイクロ秒（20回中20回成功）。この値には信号を出すためのdigitalWrite()（4.98µs）が含まれるので、割り込みそのものの応答は約6.2µsです。UNO R4は5.00µsでした。

割り込みの中でやってはいけない3つ

「ISRは短く」と言われても、どれくらいから問題になるのかは書かれていないことが多いので、測りました。2kHz（周期500µs）のパルスを200ms入れて、期待される400回のうち何回拾えるかを、ISRの中に入れる処理の長さを変えて調べています。

割り込みを使った周期処理はタイマ割り込みの練習問題、消費電力と絡めた使い方はArduinoの低消費電力化ドリルで扱っています。

拡張I/O｜音を出す・パルスを測る

pinMode(2, INPUT);
analogWrite(3, 128);
delay(50);

unsigned long high_us = pulseIn(2, HIGH, 100000UL);
unsigned long low_us  = pulseIn(2, LOW, 100000UL);

/* D3 なら 493.10 Hz */
double freq = 1000000.0 / (double)(high_us + low_us);
Serial.println(freq, 2);
analogWrite(3, 0);

/* 止めるまで鳴り続ける。noTone と対で */
tone(8, 440);
delay(500);
noTone(8);

tone() の周波数は高いほどずれる

どちらのボードも高い周波数ほど誤差が大きくなります。タイマの分周が整数なので、周波数が上がるほど刻みが粗くなるためです。4000HzのR3だけ幅で書いたのは、測るたびに+5.5%と+8.2%の間で変わったからです。R4は3回とも4132.2Hzで動きませんでした。音階を正確に出したい用途では、この誤差を見込んでおく必要があります。

tone() を鳴らすとPWMが止まる（R3）

UNO R3のtone()は内部でタイマを1つ占有します。そのタイマはanalogWrite()のPWMにも使われているため、音を鳴らしている間だけ特定のピンのPWMが止まります。

D3とD5にanalogWrite(128)を出したまま、別のピン（D8）でtone()を鳴らして測りました。

出力そのものが止まります。周波数が変わるのではありません。「音を鳴らしながらLEDの明るさを変えたら、そのLEDだけ消えた」という現象は、これで説明が付きます。音と一緒にPWMを使うなら、D3以外のピンを選んでください。UNO R4では両方とも影響を受けませんでした。

通信｜Serialとその仲間

Serial.begin()で速度を決め、シリアルモニタ側も同じ速度にします。ここが食い違うと文字化けします。

Serial.begin(115200);

/* R4はUSB直結。開くまで待つ */
while (!Serial) {
    ;
}

/* F() で文字列をフラッシュへ置く */
Serial.println(F("start"));

Serial.print は850µsかかる

115200bpsで10文字を送るコストを測ったところ、UNO R3で850.0µs、UNO R4で868.5µsでした。10文字＝100ビットぶんの送信時間（約868µs）とほぼ一致します。通信の速さそのものが上限になっているということです。

シリアル通信の使い方そのものはArduinoのシリアル通信入門｜Serial.printとデータ受信の練習問題にまとめています。

数学・ビット・文字・乱数

map()がR3で40µs近くかかるのは意外に思われるかもしれませんが、8bitのマイコンには割り算の回路がありません。センサ値を毎回map()で変換するループでは、これが積み上がります。

ビット操作の考え方はC言語のビット演算｜マスク・シフトの練習問題で扱っています。

/* 0〜1023 を 0〜100 へ直す */
int raw = analogRead(A0);
int pct = map(raw, 0, 1023, 0, 100);

/* 範囲外を丸める */
pct = constrain(pct, 0, 100);

/* 0ビット目を1にして、読み返す */
uint8_t flags = 0;
bitSet(flags, 0);
bool on = bitRead(flags, 0);

型・定数・修飾子

配列・構造体・ポインタといったC言語側の話はC言語の配列、構造体、組み込みでのポインタで扱っています。

/* R3: 2 / R4: 4 */
Serial.println((int)sizeof(int));

/* R3: 4 / R4: 4 */
Serial.println((int)sizeof(long));

/* R3: 4 / R4: 8 */
Serial.println((int)sizeof(double));

/* R3: 2 / R4: 4 */
Serial.println((int)sizeof(void *));

UNO R3とUNO R4で違うところ

UNO R3のマイコンはAVRのATmega328P（16MHz）、UNO R4はルネサス RA4M1（48MHz）です。互換性を保つよう作られていますが、中身は別物なので変わるところがあります。

速さ

おおむねR4が速いのですが、analogWrite()だけはR4が3倍おそいという結果でした。PWMの設定を書き換えるたびに呼ぶ処理では、ここで時間を取られる可能性があります。

挙動

型の大きさ（移植するときに問題になる）

intに32768以上を入れるコードはR3では壊れ、R4では動きます。逆にintのサイズを2バイト前提で書いたコードは、R4で意図しない動きになります。移植するならintではなくint16_tやint32_tで書くのが安全です。

R4だけコンパイルが通らないとき

R3ではRAMが先に尽きる

UNO R3のRAMは2KBしかありません。AVRでは文字列リテラルがRAMに置かれるため、Serial.print("...")を並べるだけで足りなくなります。この記事の計測スケッチも、最初はRAMを3,542バイト（172%）使ってコンパイルが通りませんでした。

最大2048バイトのRAMのうち、グローバル変数が3542バイト（172%）を使っていて、
ローカル変数で-1494バイト使うことができます。
data section exceeds available space in board

直し方はF()で文字列をフラッシュ側へ移すことです。

/* RAMに置かれる */
Serial.println("digitalWrite の実測");

/* フラッシュに置かれる */
Serial.println(F("digitalWrite の実測"));

この置き換えだけで3,542バイト→254バイト（12.4%）まで下がりました。UNO R4はRAMが32KBあるので、この対処は要りません。R3向けのコードにPROGMEMやF()が出てくるのは、この2KBという制約のためです。

この数字の測り方（同じことを手元で再現する）

測定は1つのスケッチにまとめてあります。使うのはジャンパ3本（D3とD2、D5とD4、D8とD7）と、ブレッドボードに組む3つの回路（分圧、RCローパス、プルアップ測定）です。あとはArduino IDEで書き込み、シリアルモニタを115200bpsで開くだけです。

よくあるつまずき

まとめ

Arduinoの関数は、分類さえ分かれば公式ドキュメントからでも引けます。この記事で足したのは実際に測った数字です。

digitalWrite()は1回4.980µs、レジスタ直接なら0.056µsで89倍の差があります。analogRead()は111.792µsで、他の関数より2桁遅い。map()はR3で39.460µsかかります。どれも1回なら気にする値ではありませんが、ループの中で何万回も回ると時間に表れます。

analogWrite()が出しているのは電圧ではなく、HIGHの時間の割合です。平滑して測ると値に比例した電圧になりますが、ピンによって周波数が倍違い（R3のD3とD5）、tone()を鳴らすとD3の出力は止まります。

割り込みは11.20µsで応答しますが、ISRが割り込みの周期を超えると取りこぼし始めます。Serial.print()は10文字で850µsかかります。ISRの中で1回呼べば3〜5割落とすという関係です。

そしてUNO R4は、ほとんどの関数でR3より速い一方、analogWrite()だけ3倍おそく、intは2バイトから4バイトに変わり、割り込みは2本から14本のピンで使えます。R3で当たり前だったF()やPWM周波数の差は、R4では出てきません。

数字が必要になったらこのページに戻ってきてください。測り方も載せてあるので、手元のボードで確かめ直すこともできます。